ZScript global variables

There are two methods available for handling global variables: EventHandlers and Thinkers. Each has their advantages and disadvantages.

EventHandlers come in two flavors: EventHandler, which is only available within maps but are saved, and StaticEventHandler, which persist outside of maps but are never saved to savegames. See Events and handlers for more information on how to set up an event handler. If you have global data that only needs to be loaded once at the game's launch, consider using a StaticEventHandler so that the data doesn't need to be recalculated every time a new level is loaded.

Individual EventHandler classes can be referenced using the Find() function, as below.

class MyEventHandler : EventHandler
{
    int myGlobalInt;
}

// Example of accessing MyEventHandler from an actor.
class MyClass : Actor
{
    MyEventHandler event;

    override void PostBeginPlay()
    {
        super.PostBeginPlay();

        // Be sure to call the proper Find() method for the type of EventHandler you are using or problems may occur.
        // EventHandler.Find() for EventHandler and StaticEventHandler.Find() for StaticEventHandler
        event = MyEventHandler(EventHandler.Find("MyEventHandler"));
        if (event)
        {
            event.myGlobalInt = 1;
            Console.Printf("My global int is: %d", event.myGlobalInt);
        }
    }
}

All Thinkers, by contrast, are saved to savegames. Using a ThinkerIterator is slower than the StaticEventHandler's Find function, but a Thinker with the statnum STAT_STATIC is the only way to store information for the duration of a play session, saved and loaded or not. This performance hit can be mitigated by keeping a reference to the Thinker being used for global variables in either the actors needing to reference it or another, higher global variable keeper, such as an EventHandler.

class MyGlobalVariables : Thinker
{
    int testVar;

    static MyGlobalVariables Get()
    {
        ThinkerIterator it = ThinkerIterator.Create("MyGlobalVariables", STAT_INFO); // Change this to STAT_STATIC if your thinker persists between maps.
        let p = MyGlobalVariables(it.Next());
        if (!p)
        {
            p = new("MyGlobalVariables");
            p.ChangeStatNum(STAT_INFO); // Change this to STAT_STATIC if persisting between maps is desired.
        }

        return p;
    }
}

// Example of an actor accessing the above thinker's variables.
class MyClass : Actor
{
    MyGlobalVariables globalVars;

    override void PostBeginPlay()
    {
        super.PostBeginPlay();

        globalVars = MyGlobalVariables.Get();
        if (globalVars)
        {
            globalVars.testVar++;
            Console.Printf("My global int is: %d", globalVars.testVar);
        }
    }
}