Classes:FWeapQuietus


Classes: Inventory→Weapon→FighterWeapon→FWeapQuietus
The Fighter's final weapon, the Quietus is a very powerful sword that sends out a spread of green balls. It is recommended for use in short range, so all projectiles strike the target, inflicting serious damage. It uses 14 mana of each kind per attack.

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things:
  1. You do not need to copy that actor, since it is already defined.
  2. In fact, it's not just useless, it's actually harmful as it can cause problems.
  3. If you want to modify it, or use a modified version, using inheritance is the way to go.
  4. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.
  5. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.
Quietus
Actor type Weapon Game
DoomEd Number None Class Name FWeapQuietus

DECORATE definition

 
ACTOR FWeapQuietus : FighterWeapon
{
  Health 3
  Weapon.SelectionOrder 2900
  +WEAPON.PRIMARY_USES_BOTH
  +INVENTORY.NOATTENPICKUPSOUND
  Weapon.AmmoUse1 14
  Weapon.AmmoUse2 14
  Weapon.AmmoGive1 20
  Weapon.AmmoGive2 20
  Weapon.KickBack 150
  Weapon.YAdjust 10
  Weapon.AmmoType1 "Mana1"
  Weapon.AmmoType2 "Mana2"
  Inventory.PickupMessage "$TXT_WEAPON_F4"
  Inventory.PickupSound "WeaponBuild"
  Tag "$TAG_FWEAPQUIETUS"

  action native A_FSwordAttack();

  States
  {
  Spawn:
    TNT1 A -1
    Stop
  Select:
    FSRD A 1 Bright A_Raise
    Loop
  Deselect:
    FSRD A 1 Bright A_Lower
    Loop
  Ready:
    FSRD AAAABBBBCCCC 1 Bright A_WeaponReady
    Loop
  Fire:
    FSRD DE 3 Bright Offset(5, 36)
    FSRD F 2 Bright Offset(5, 36)
    FSRD G 3 Bright Offset(5, 36) A_FSwordAttack
    FSRD H 2 Bright Offset(5, 36)
    FSRD I 2 Bright Offset(5, 36)
    FSRD I 10 Bright Offset(5, 150)
    FSRD A 1 Bright Offset(5, 60)
    FSRD B 1 Bright Offset(5, 55)
    FSRD C 1 Bright Offset(5, 50)
    FSRD A 1 Bright Offset(5, 45)
    FSRD B 1 Bright Offset(5, 40)
    Goto Ready
  }
}
This article is issued from Zdoom. The text is licensed under Creative Commons - Attribution - Sharealike. Additional terms may apply for the media files.